Apple Macintosh CD: Power Macintosh 5200/75/Apple Macintosh CD - Power Macintosh 5200_75.7z/Apple Macintosh CD - Power Macintosh 5200_75.bin/Extras/PowerTalk Extras/PowerTalk Mail Gateways/STF PowerFax™ PE Gateway/PowerFax™ PE Installer/STFApplications.sit/ARA Scripts/ZyXEL (LnMgr)

Text File | 1994-07-11 | 3KB | 204 lines

! "ZyXEL U-1496 and U-1496E"
! This script has been verified to work with Line Manager
!
@ORIGINATE
@ANSWER
!
@LABEL 1
serreset 19200, 0, 8, 1
!
! first recall the factory configuration
!
matchclr
matchstr 1 4 "OK\13\10"
write "AT&F\13"
matchread 30
jump 59
!
! Next, Set up the configuration:
!
@LABEL 4
pause 5
matchstr 1 6 "OK\13\10"
! &K0: No error control (default &K4)
! &M2: Direct async. mode (default &M0)
! &B0: DTE/DCE rate follows link rate (default &B1)
! X4 : Result code and call progress monitor option (default X5)
! S0=0: Turn off auto-answer
! E0: Turn off echo
write "AT&K0&M2&B0X4S0=0E0 \13"
matchread 30
jump 59
!
! If speaker on flag is true, jump to label 8. Else turn off speaker.
!
@LABEL 6
ifstr 2 8 "1"
matchstr 1 8 "OK\13\10"
write "ATM0\13"
matchread 30
jump 59
!
! The modem is ready so enable answering, or originate a call
!
@LABEL 8
pause 5
ifANSWER 30
note "Dialing ^1" 3
write "ATDT^1\13"
!
@LABEL 9
matchstr 1 11 "CONNECT 1200\13\10"
matchstr 2 12 "CONNECT 2400\13\10"
matchstr 3 13 "CONNECT 4800\13\10"
matchstr 4 14 "CONNECT 7200\13\10"
matchstr 5 15 "CONNECT 9600\13\10"
matchstr 6 16 "CONNECT 12000\13\10"
matchstr 7 17 "CONNECT 14400\13\10"
matchstr 8 50 "NO CARRIER\13\10"
matchstr 9 50 "ERROR\13\10"
matchstr 10 52 "NO DIALTONE\13\10"
matchstr 11 53 "BUSY\13\10"
matchstr 12 54 "NO ANSWER\13\10"
matchread 700
jump 59
!
@LABEL 11
note "Communicating at 1200 bps." 2
setspeed 1200
jump 20
!
@LABEL 12
note "Communicating at 2400 bps." 2
setspeed 2400
jump 20
!
@LABEL 13
note "Communicating at 4800 bps." 2
setspeed 4800
jump 20
!
@LABEL 14
note "Communicating at 7200 bps." 2
setspeed 7200
jump 20
!
@LABEL 15
note "Communicating at 9600 bps." 2
setspeed 9600
jump 20
!
@LABEL 16
note "Communicating at 12000 bps." 2
setspeed 12000
jump 20
!
@LABEL 17
note "Communicating at 14400 bps." 2
setspeed 14400
jump 20
!
! Finished. Return with good results
@LABEL 20
exit 0
!
! @ANSWER
! Set up the modem to answer
@LABEL 30
write "ATS0=1\13"
matchstr 1 31 "OK\13\10"
matchread 30
jump 59
!
@LABEL 31
matchstr 1  32 "RING\13\10"
matchstr 2  11 "CONNECT 1200\13\10"
matchstr 3  12 "CONNECT 2400\13\10"
matchstr 4  13 "CONNECT 4800\13\10"
matchstr 5     14 "CONNECT 7200\13\10"
matchstr 6  15 "CONNECT 9600\13\10"
matchstr 7     16 "CONNECT 12000\13\10"
matchstr 8  17 "CONNECT 14400\13\10"
matchstr 9  50 "NO CARRIER\13\10"
matchstr 10    50 "ERROR\13\10"
matchstr 11    52 "NO DIALTONE\13\10"
matchstr 12    53 "BUSY\13\10"
matchstr 13 54 "NO ANSWER\13\10"
matchread 700
jump 31
!
@LABEL 32
userhook 1
note "Answering phone…" 2
jump 31
!
! 50: error messages
!
@LABEL 50
exit -6021
!
@LABEL 52
exit -6020
!
@LABEL 53
exit -6022
!
@LABEL 54
exit -6023
!
@LABEL 59
exit -6019
!
@LABEL 70
setspeed 19200
jump 71
!
! Hang up the modem
!
@HANGUP
@LABEL 60
settries 0
HSReset 0 0 0 0 0 0
@LABEL 61
write "ATH\13"
matchclr
matchstr 1 62 "NO CARRIER\13\10"
matchstr 2 62 "OK\13\10"
matchstr 3 62 "ERROR\13\10"
matchread 30
inctries
iftries 3 59
iftries 2 70
!
@LABEL 71
! no response, try escape sequence
pause 12
write "+++"
matchclr
matchstr 1 61 "OK\13\10"
matchread 18
! try dropping DTR
DTRClear
pause 15
DTRSet
pause 15
jump 61
!
@LABEL 62
! recall the factory settings
pause 15
write "AT&F\13"
matchclr
matchstr 1 63 "OK\13\10"
matchread 30
!
@LABEL 63
pause 5
matchstr 1 64 "OK\13\10"
write "ATS0=0\13"
matchread 20
!
@LABEL 64
exit 0